Forum zur gegenseitigen Hilfe für Hobby´s, Spass und Technik, im Raum Penzberg, Garmisch, Bad Tölz, Seeshaupt
Forum zur gegenseitigen Hilfe für Hobby´s, Spass und Technik, im Raum Penzberg, Garmisch, Bad Tölz, Seeshaupt
dann schaut nochmal genau in dem Link. Die am kleinsten geschriebene Zeile und auch noch in hellgrau, dass man es ja nicht betrachtet, da steht "Versand erfolgt unverklebt" 
Die zu langen Kabel sind im Kanal verschwunden. Code: Alles auswählen
// Arduino Pool_Solarheizung_Pumpensteuerung
#include <OneWire.h>
#include <DallasTemperature.h>
#include "Wire.h"
#include <LiquidCrystal_I2C.h>
LiquidCrystal_I2C lcd(0x27, 20, 4);
//-----Motortreiber----
const byte RPWM = 10;
const byte LPWM = 11;
const byte Poti1 = A0;
const byte Poti2 = A1;
byte Tasterstatur = 0;
const byte Taster = 4;
byte Pumpe = 0;
int P1 = 0;
int P2 = 0;
int Drehzahl = 0;
int Solldrehzahl = 0;
int Sollalt = 10;
byte Anfahren = 0;
int Drehzahlmin = 150;
int Drehzahlmax = 255;
unsigned long millisekunden = 0;
unsigned long Sekundenablauf01 = 0; // Messung Potis und Ausgabe Display
const unsigned long Pausezeit01 = 1000;
unsigned long Sekundenablauf02 = 0; // Display nach Zeit ausschalten
const unsigned long Pausezeit02 = 60000 * 5; // 5 Minuten
const unsigned char One_Wire_Bus = 2; // Sensoren auf Pin 2
OneWire oneWire(One_Wire_Bus);
DallasTemperature sensoren (&oneWire);
int Anzahl_Sensoren = 0;
int is = 0; // Zähler für die Sensoren
int ia = 0; // Zähler für die Adressstellen 0-7
int Sensor = 0;
float temppool = 0;
float tempsolar = 0;
float tempdif = 0;
DeviceAddress tempDeviceAddress; // Für die Adressausgabe
int numberOfDevices; // Für die Adressausgabe
//##########################################################################
//################################ Setup ##################################
//##########################################################################
void setup() {
Wire.begin();
sensoren.begin();
Serial.begin(9600);
lcd.begin();
lcd.backlight();
lcd.setCursor (0, 0);
lcd.print (F("Solarheizung - Pool"));
lcd.setCursor (0, 1);
lcd.print (F("Soll"));
lcd.setCursor (10, 1);
lcd.print (F("Ist"));
lcd.setCursor (0, 2);
lcd.print (F("Soll"));
lcd.setCursor (10, 2);
lcd.print (F("Ist"));
lcd.setCursor (0, 3);
lcd.print (F("Soll Ist"));
// Anzahl der Sesoren ermitteln-------------------------------------
Anzahl_Sensoren = sensoren.getDeviceCount();
// Ermitteln der Sensor-Adressen------------------------------------
for (is = 0; is < Anzahl_Sensoren; is++)
{
if (sensoren.getAddress(tempDeviceAddress, is))
{
Serial.println ();
printAddress(tempDeviceAddress);
}
}
//-----------Aus-/Eingänge einrichten-------------------------------------
pinMode(RPWM, OUTPUT); // PWM Pumpensteuerung
pinMode(LPWM, OUTPUT); // PWM Pumpensteuerung
pinMode(Poti1, INPUT);
pinMode(Poti2, INPUT);
pinMode(Taster, INPUT_PULLUP);
}
// Ausgabe der Sensor-Adressen
void printAddress(DeviceAddress deviceAddress)
{
for (uint8_t ia = 0; ia < 8; ia++)
{
if (deviceAddress[ia] < 16)
{
Serial.print("0"); //ist die Hex Adresse kleiner 16 dann erste Stelle eine "0"
}
Serial.print(deviceAddress[ia], HEX);
}
}
//###########################################################################
//################################## LOOP ###################################
//###########################################################################
void loop()
{
millisekunden = millis();
//---------------------------------Taster für Display abfragen-------------
Tasterstatur = digitalRead(Taster);
if (Tasterstatur == LOW)
{
lcd.backlight();
Sekundenablauf02 = millisekunden;
}
if (millisekunden - Sekundenablauf02 >= Pausezeit02) // Dislay Zeit abgelaufen?
{
lcd.noBacklight();
}
//-------------------Hauptptogramm jede Sekunde durcharbeiten--------------
if (millisekunden - Sekundenablauf01 >= Pausezeit01) // Eine Sekunde abgelaufen?
{
P1 = analogRead (Poti1);
P1 = map(P1, 0, 1023, 0, 30); // -------Solltemperatur Einstellung-------
P2 = analogRead (Poti2);
P2 = map(P2, 0, 1023, 0, 10);
lcd.setCursor (5, 1);
lcd.print (P1);
lcd.print (" ");
lcd.setCursor (5, 2);
lcd.print (P2);
lcd.print (" ");
lcd.setCursor (5, 3);
lcd.print (Solldrehzahl);
lcd.print (F(" "));
lcd.setCursor (14, 3);
lcd.print (Drehzahl);
lcd.print (F(" "));
Sekundenablauf01 = millisekunden;
// -------------------------Temperatur Auswertung---------------------------
//Temperaturen Aulesen
sensoren.requestTemperatures();
// Hier werden die Temp-Sensoren ausgelesen und aufs Display gebracht
if (Sensor < 2) {
Sensor ++;
float temperatur = sensoren.getTempCByIndex(Sensor - 1);
if (Sensor == 1) {
temppool = temperatur; // -----------Ist Temperatur Messung-------------
//temppool = 23;//!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
lcd.setCursor (14, 1);
lcd.print (temppool);
lcd.print (F(" "));
}
if (Sensor == 2) {
tempsolar = temperatur;// ----------Ist Solar_Temperatur Messung--------
//tempsolar = 26;//!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
tempdif = tempsolar - temppool; // --Ist Themperatur Differenz----------
lcd.setCursor (14, 2);
lcd.print (tempdif);
lcd.print (F(" "));
//---------------------------------------Solldrehzahl aus TemperaturDifferenz
Solldrehzahl = map(tempdif, 0, 6, 0, 255);
if (Solldrehzahl > Drehzahlmax)
{
Solldrehzahl = Drehzahlmax;
}
else
{
if (Solldrehzahl < Drehzahlmin)
{
Solldrehzahl = 0;
}
}
}
if (Sensor == Anzahl_Sensoren) Sensor = 0;
}
//------------------Pumpen Ansteuerung------------------------------------
// Wenn Temperaturdifferenz gleich/größer eingestellte Differenz dann Pumpe Maximal
if (Anfahren == 0)
{
if (tempdif >= P2)
{
Solldrehzahl = Drehzahlmax;
}
if (tempdif < P2)
{
Solldrehzahl = 150;
}
// Ist aber die Wunsch-Temperatur erreicht, dann keine Solar Unterstützung mehr
if (temppool > P1)
{
Solldrehzahl = 0;
}
if (Solldrehzahl < Sollalt)
{
Drehzahl = Solldrehzahl;
Sollalt = Solldrehzahl;
}
}
if (Solldrehzahl > Sollalt)
{
Drehzahl = Drehzahl + 10;
if (Drehzahl > 255)
{
Drehzahl = 255;
}
Sollalt = Drehzahl;
Anfahren = 1;
}
else
{
Anfahren = 0;
}
analogWrite(RPWM, Drehzahl);
analogWrite(LPWM, 0);
}//------------------Hauptprogramm Ende. Wird jede Sekunde 1x durchlaufen-----
}
Mitglieder in diesem Forum: 0 Mitglieder und 3 Gäste